sqlserver 作业调度(作业常用的几个步骤)

--【作业常用的几个步骤】
EXEC msdb.dbo.sp_delete_job
EXEC msdb.dbo.sp_add_job
EXEC msdb.dbo.sp_add_jobstep
EXEC msdb..sp_add_jobschedule
EXEC msdb.dbo.sp_add_jobserver
EXEC msdb.dbo.sp_start_job

--删除作业
IF  EXISTS (SELECT JOB_ID FROM MSDB.DBO.SYSJOBS_VIEW WHERE NAME =N‘作业名称‘)
EXECUTE MSDB.DBO.SP_DELETE_JOB @JOB_NAME=N‘作业名称‘ 

--定义创建作业
DECLARE @jobid uniqueidentifier
EXEC msdb.dbo.sp_add_job
        @job_name = N‘作业名称‘,
        @job_id = @jobid OUTPUT

--定义作业步骤
DECLARE @sql nvarchar(400),@dbname sysname
SELECT    @dbname=DB_NAME(), --执行的数据库(当前)
        @sql=N‘作业步骤内容‘ --一般定义的是使用TSQL处理的作业,这里定义要执行的Transact-SQL语句
EXEC msdb.dbo.sp_add_jobstep
        @job_id = @jobid,
        @step_name = N‘作业步骤名称‘,
        @subsystem = ‘TSQL‘, --步骤的类型,一般为TSQL
        @database_name=@dbname,
        @command = @sql

--创建调度(使用后面专门定义的几种作业调度模板)
EXEC msdb..sp_add_jobschedule
        @job_id = @jobid,
        @name = N‘调度名称‘,
        @freq_type=4,                --每天
        @freq_interval=1,            --指定每多少天发生一次,这里是1天.
        @freq_subday_type=0x8,       --重复方式,0x1=在指定的时间,0x4=多少分钟,0x8=多少小时执行一次
        @freq_subday_interval=1,     --重复周期数,这里每小时执行一次
        @active_start_date = NULL,   --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD
        @active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD
        @active_start_time = 00000, --作业执行的开始时间,格式为HHMMSS
        @active_end_time = 235959    --作业执行的停止时间,格式为HHMMSS

--添加目标服务器
DECLARE @servername sysname
SET @servername=CONVERT(nvarchar(128),SERVERPROPERTY(N‘ServerName‘))--当前SQL实例
EXEC msdb.dbo.sp_add_jobserver
        @job_id = @jobid,
        @server_name = @servername 

-----------------------------------------------------------------------------------------------
--调度模板定义 sp_add_jobschedule

--只执行一次的作业调度
EXEC msdb..sp_add_jobschedule
        @job_id = @jobid,
        @name = N‘调度名称‘,
        @freq_type=1,                --仅执行一次
        @active_start_date = NULL,   --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD
        @active_start_time = 00000   --作业执行的开始时间,格式为HHMMSS

--日调度
EXEC msdb..sp_add_jobschedule
        @job_id = @jobid,
        @name = N‘调度名称‘,
        @freq_type=4,                --每天
        @freq_interval=1,            --指定每多少天发生一次,这里是1天.
        @freq_subday_type=0x8,       --重复方式,(0x1=指定的时间;0x4=多少分钟;0x8=多少小时)执行一次
        @freq_subday_interval=1,     --重复周期数,这里每小时执行一次
        @active_start_date = NULL,   --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD
        @active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD
        @active_start_time = 00000, --作业执行的开始时间,格式为HHMMSS
        @active_end_time = 235959    --作业执行的停止时间,格式为HHMMSS

--周调度
EXEC msdb.dbo.sp_add_jobschedule
        @job_id = @jobid,
        @name = N‘调度名称‘,
        @freq_type = 8,              --每周
        @freq_recurrence_factor = 1, --每多少周执行一次,这里是每周
        @freq_interval = 62,         --在星期几执行,由POWER(2,N)表示,N的值为0~6,代表星期日~星期六,如果指定两个,则将值相加,例如,值为65表示在星期天和星期日执行(POWER(2,0)+POWER(2,6))
        @freq_subday_type = 0x8,     --重复方式,0x1=在指定的时间,0x4=多少分钟,0x8=多少小时执行一次
        @freq_subday_interval = 1,   --重复周期数,这里每小时执行一次
        @active_start_date = NULL,   --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD
        @active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD
        @active_start_time = 00000, --作业执行的开始时间,格式为HHMMSS
        @active_end_time = 235959    --作业执行的停止时间,格式为HHMMSS

--月调度(每X个月的每月几号)
EXEC msdb.dbo.sp_add_jobschedule
        @job_id = @jobid,
        @name = N‘调度名称‘,
        @freq_type = 16,             --每月
        @freq_recurrence_factor = 2, --每多少月执行一次,这里是每2个月
        @freq_interval = 2,          --在执行月的第几天执行,这里是第2天
        @freq_subday_type = 0x8,     --重复方式,0x1=在指定的时间,0x4=多少分钟,0x8=多少小时执行一次
        @freq_subday_interval = 1,   --重复周期数,这里每小时执行一次
        @active_start_date = NULL,   --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD
        @active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD
        @active_start_time = 00000, --作业执行的开始时间,格式为HHMMSS
        @active_end_time = 235959    --作业执行的停止时间,格式为HHMMSS

--月调度(每X个月的相对时间)
EXEC msdb.dbo.sp_add_jobschedule
        @job_id = @jobid,
        @name = N‘调度名称‘,
        @freq_type = 32,             --每月
        @freq_recurrence_factor = 2, --每多少月执行一次,这里是每2个月
        @freq_interval = 9,          --在当月的那个时间执行,1~7=星期日至星期六,8=日 ,9=工作日,10=周末
        @freq_relative_interval = 1, --在第几个相对时间执行,允许的值为1,2,4,8代表第1~4个相对时间,16表示最后一个相对时间
        @freq_subday_type = 0x8,     --重复方式,0x1=在指定的时间,0x4=多少分钟,0x8=多少小时执行一次
        @freq_subday_interval = 1,   --重复周期数,这里每小时执行一次
        @active_start_date = NULL,   --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD
        @active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD
        @active_start_time = 00000, --作业执行的开始时间,格式为HHMMSS
        @active_end_time = 235959    --作业执行的停止时间,格式为HHMMSS

--在特定时候执行的作业调度
EXEC msdb.dbo.sp_add_jobschedule
        @job_id = @jobid,
        @name = N‘调度名称‘,
        @freq_type = 64     --64=在SQLServerAgent 服务启动时运行,128=计算机空闲时运行

-----------------------------------------------------------------------------------------------
IF EXISTS (SELECT * FROM DBO.SYSOBJECTS WHERE ID = OBJECT_ID(N‘[DBO].SP_AUTO_CREATEJOB‘) AND OBJECTPROPERTY(ID, N‘ISPROCEDURE‘) = 1)
DROP PROCEDURE [DBO].SP_AUTO_CREATEJOB
GO

CREATE PROCEDURE DBO.SP_AUTO_CREATEJOB
                        @DBNAME VARCHAR(100),    --执行数据库
                        @JOBNAME VARCHAR(100),
                        @EXECSQL NVARCHAR(4000)    --执行语句
AS
PRINT ‘----作业 :‘+@JOBNAME
PRINT ‘----开始执行:‘  +@EXECSQL

BEGIN TRANSACTION
DECLARE
    @JOBID UNIQUEIDENTIFIER,
    @RETURNCODE INT
    SELECT @RETURNCODE = 0
BEGIN
    IF  EXISTS (SELECT JOB_ID FROM MSDB.DBO.SYSJOBS_VIEW WHERE NAME =@JOBNAME)
    EXECUTE MSDB.DBO.SP_DELETE_JOB @JOB_NAME=@JOBNAME 

    EXECUTE @RETURNCODE = MSDB.DBO.SP_ADD_JOB        --返回值:0成功,1失败
                        @JOB_NAME = @JOBNAME,
                        @ENABLED = 1,                --状态。默认值为 1(启用),为 0 不启用
                        @OWNER_LOGIN_NAME = ‘SA‘,    --拥有作业的登录名。默认值为 NULL,可解释为当前登录名
                        @JOB_ID = @JOBID OUTPUT
    IF (@@ERROR <> 0 OR @RETURNCODE <> 0) GOTO QUITWITHROLLBACK  

    EXECUTE @RETURNCODE = MSDB.DBO.SP_ADD_JOBSTEP
                        @JOB_ID = @JOBID,
                        @STEP_NAME = N‘STEP1‘,        --步骤名称
                        @SUBSYSTEM = ‘TSQL‘,        --步骤的类型,一般为TSQL
                        @DATABASE_NAME = @DBNAME,    --执行数据库
                        @COMMAND = @EXECSQL            --执行语句
    IF (@@ERROR <> 0 OR @RETURNCODE <> 0) GOTO QUITWITHROLLBACK     

    EXECUTE @RETURNCODE = MSDB.DBO.SP_UPDATE_JOB
                        @JOB_ID = @JOBID,
                        @START_STEP_ID = 1            --作业中要执行的第一个步骤的标识号
    IF (@@ERROR <> 0 OR @RETURNCODE <> 0) GOTO QUITWITHROLLBACK 

    EXECUTE @RETURNCODE = MSDB.DBO.SP_ADD_JOBSERVER
                        @JOB_ID = @JOBID,
                        @SERVER_NAME = N‘(LOCAL)‘
    IF (@@ERROR <> 0 OR @RETURNCODE <> 0) GOTO QUITWITHROLLBACK    

END
COMMIT TRANSACTION  

GOTO ENDSAVE  

QUITWITHROLLBACK:
    IF (@@TRANCOUNT > 0)
    BEGIN
        ROLLBACK TRANSACTION
        RETURN 1
    END   

ENDSAVE:
EXEC @RETURNCODE = MSDB.DBO.SP_START_JOB @JOB_ID = @JOBID  --启动作业
RETURN @RETURNCODE  

 
时间: 12-26

sqlserver 作业调度(作业常用的几个步骤)的相关文章

sqlserver定时作业,定时执行存储过程

首先,我想说,我真的是渣了,一个这个玩意弄了半天,算了,直接切入正题吧. 第一步: 先写好存储过程 用了两张表,你们自己建立吧 if exists(select name from sysobjects where name='StaySchoolNum'and type='p') drop proc StaySchoolNum go create proc StaySchoolNum as declare @init int,@totle int select @init=count(*) f

SQL Server代理(2/12):作业步骤和子系统

SQL Server代理是所有实时数据库的核心.代理有很多不明显的用法,因此系统的知识,对于开发人员还是DBA都是有用的.这系列文章会通俗介绍它的很多用法. SQL Server代理作业有一系列的一个或多个作业步骤组成.一个作业步骤会分配给特定的作业子系统,用来标识将要进行的作业步骤工作种类.每个作业步骤在各自安全上下文运行,尽管每个作业有可以决定谁可以修改作业的拥有者.这篇文章会聚焦组成SQL Server代理作业的作业步骤和子系统. 作业的快速回顾 认为SQL Server代理作业的最好方式

怎样查出SQLServer的性能瓶颈

--王成辉翻译整理,转贴请注明出自微软BI开拓者[url]www.windbi.com[/url]--原帖地址 如果你曾经做了很长时间的DBA,那么你会了解到SQLServe的性能调优不是一个精密的科学.即使是,对于为最佳的性能找到最佳的配置也是很困难的.这是因为对于调优来说很少东西是绝对的.例如,一个性能调优可能对某一方面有用,可是却会影响其他的性能. 我曾经做过DBA,在最后7年的日子里,我总结了一套SQLServer调优的清单.当第一次进行SQLServer性能调优的时候,可以用它来作为一

创建作业的SQL

创建备份MYDB的备份脚本,并删除5天前备份 USE msdb ; GO EXEC dbo.sp_add_job     @job_name = 'Job_backup_DB',  --作业的名称     @enabled = 1, --指示添加的作业的状态(默认值为(启用))     @description = '数据库定期备份作业!', --作业的说明     @owner_login_name = 'sa', --拥有作业的登录名     @notify_level_eventlog =

spark总结——转载

转载自:http://smallx.me/2016/06/07/spark%E4%BD%BF%E7%94%A8%E6%80%BB%E7%BB%93/ 第一个Spark程序 /** * 功能:用spark实现的单词计数程序 * 环境:spark 1.6.1, scala 2.10.4 */ // 导入相关类库import org.apache.spark._ object WordCount { def main(args: Array[String]) { // 建立spark运行上下文 val

【转】大数据批处理框架 Spring Batch全面解析

如今微服务架构讨论的如火如荼.但在企业架构里除了大量的OLTP交易外,还存在海量的批处理交易.在诸如银行的金融机构中,每天有3-4万笔的批处理作业需要处理.针对OLTP,业界有大量的开源框架.优秀的架构设计给予支撑:但批处理领域的框架确凤毛麟角.是时候和我们一起来了解下批处理的世界哪些优秀的框架和设计了,今天我将以Spring Batch为例,和大家一起探秘批处理的世界.初识批处理典型场景探秘领域模型及关键架构实现作业健壮性与扩展性批处理框架的不足与增强批处理典型业务场景对账是典型的批处理业务处

SQL JOB

数据库同步是一种比较常用的功能.以下结合我自己的体会整理的,如果有理解不完全或者有误的地方望大牛不理赐教.下面介绍的就是数据库同步的两种方式: 1.SQL JOB的方式 sql Job的方式同步数据库就是通过SQL语句,将一个数据源中的数据同步到目标数据库中.特点是它可以灵活的通过SQL的方式进行数据库之间的同步操作.可以在制定的时间时间作为任务计划自动执行.缺点是需要写SQL来进行操作.既然是数据库之间的同步就涉及到数据库之间的连接.建立连接是同步的第一步.SQL Server建立连接可以通过

剑指Offer——知识点储备-数据库基础

剑指Offer--知识点储备-数据库基础 数据库 事务 事务的四个特性(ACID): ??原子性(Atomicity).一致性(Consistency).隔离性(Isolation).持久性(Durability) - (1)原子性 整个事务中的所要操作要么全部提交成功,要么全部失败回滚. - (2)一致性 保证数据库中的数据操作之前和操作之后的一致性.(比如用户多个账户之间的转账,但是用户的总金额是不变的) - (3)隔离性 隔离性要求一个事务对数据库中数据的修改,在未提交完成前对于其它事务是

iOS 关于版本升级问题的解决

从iOS8系统开始,用户可以在设置里面设置在WiFi环境下,自动更新安装的App.此功能大大方便了用户,但是一些用户没有开启此项功能,因此还是需要在程序里面提示用户的. 虽然现在苹果审核不能看到版本提示更新的功能和字样以及功能.但是有的app策划还是要提供这些功能.这里主要提供两种思路. 方法一 在服务器接口约定对应的数据,这样,服务器直接传递信息,提示用户有新版本,可以去商店升级 但是这个方法是有问题的,由于您的app在审核过程中 不能出现更新字样,所以在审核过程中就需要接口的返回的字段是新版